Ταξινόμηση Φυσαλίδας (bubble sort)

Το πρόγραμμα παρουσιάζει στη οθόνη τίτλο, και τρεις στήλες, μια στήλη για τις αλλαγές που γίνονται και δυο για τον πίνακα χωρίς σειρά και σε σειρά.
Υπάρχουν δυο σημειώσεις, για να αλλάξουμε το πίνακα, να βάλουμε ένα ήδη ταξινομημένο και έναν με την αντίστροφη σειρά.
Γίνεται χρήση του φορμαρίσματος της οθόνης.

\\ ταξινόμηση φυσαλίδας
πλατος_στήλης=8
Φόρμα πλατος_στήλης*6,30
\\ οι τύπωσε πάνω/μέρος/υπό είναι μια ιδιαιτερότητα της Μ2000
\\ είναι παραλλαγές πολύ χρήσιμες
\\ μια δυνατότητά τους είναι ότι οι αλλαγές εμφάνισης με την $() είναι προσωρινές
\\ εδώ επιλέγω κεντραρισμένη μη αναλογική γραμμή (με το 6 έχω κεντραρισμένη αναλογική γραφή)
Οθόνη 12
Πένα 11 {
      Διπλά
      Τύπωσε Πάνω $(2), "Ταξινόμηση Φυσαλίδας"  \ διαγράφει ότι έχει η γραμμή πρώτα
      Τύπωσε Υπό \\ υπογραμμίζει και αλλάζει γραμμή
      Κανονικά
}
Οθόνη 5,2
Τύπωσε $(0,πλατος_στήλης) \\ καθορίζει επέκταση στα αλφαριθμητικά και στήλη των 12 χαρακτήρων
\\ οι στοιχίσεις θα είναι αριστερή για αλφαριθμητικά και δεξιά για αριθμούς
Τύπωσε μέρος "Αλλαγές", @(στηλη(2)), $(6),"Χωρίς Σειρά", "Σε σειρά"
Τύπωσε υπό
όριο=19
Πίνακας α(όριο+1), β()
\\ σε  τυχαία σειρά
α(0)=19,10,150,9,18,6,5,40,3,2,219,10,150,39,718,67,51,40,33,12
\\ σε ανάποδη σειρά
Σημ : Για ι=0 Έως όριο : α(ι)=(όριο-ι)*10 : Επόμενο ι
\\ σε σειρά
Σημ : Για ι=0 Έως όριο : α(ι)=ι*10 : Επόμενο ι
β()=α()
Για ι=0 Έως όριο-1 {
      Για κ=όριο Έως ι {
            Αν α(ι)>α(κ) Τότε {
                  Άλλαξε α(ι),α(κ)
                  Πένα 11 {
                        Τύπωσε Μέρος μορφη$("[{0}]:{1} <-> [{2}]:{3}",κ,α(κ),ι,α(ι))
                        Τύπωσε
                  }
            }
      }
}
Δρομέας 0,3
Πένα 15 {
      Για ι=0 Έως όριο {
            Τύπωσε μέρος @(στηλη(2)), $(6), β(ι), α(ι)
            Τύπωσε
      }
}
Οθόνη ,-3