Integer Square Root (Addition: BigInteger)

Update: https://rosettacode.org/wiki/Isqrt_(integer_square_root)_of_X#M2000_Interpreter

Check function IntSqrt using BigInteger at the the last part of module integer_square_root

module integer_square_root (f=-2) {
	Locale 1033
	function comma$(a) {
		string z,  f, p
		const c$=locale$(15)
		if type$(a)="BigInteger" then z=str$(a) else z=a
		long m=len(z)
		z=strrev$(z)
		for i=1 to len(z) step 3
			p=mid$(z,i, 3)
			f+=p+if$(m-i>=3->c$,"")
		next
		=strrev$(f)
	}	
	function IntSqrt(x as long long) {
		long long q=1, z=x, t, r
		do q*=4&& : until (q>x)
		while q>1&&
			q|div 4&&:t=z-r-q:r|div 2&&
			if t>-1&& then z=t:r+= q
		end while
		=r
	}
	long i
	print #f, "The integer square root of integers from 0 to 65 are:"
	for i=0 to 65
		print #f, IntSqrt(i)+" ";
	next
	print #f
	print #f, "Using Long Long Type"
	print #f, "The integer square roots of powers of 7 from 7^1 up to 7^21 are:"
	for i=1 to 21 step 2 {
		print #f, "IntSqrt(7^"+i+")="+comma$(IntSqrt(7&&^i))+" of 7^"+i+" ("+comma$(7&&^I)+")"
	}
	print #f
	function IntSqrt(x as decimal) {
		decimal q=1, z=x, t, r
		do q*=4 : until (q>x)
		while q>1
			q/=4:t=z-r-q:r/=2
			if t>-1 then z=t:r+= q
		end while
		=r
	}
	print #f, "Using Decimal Type"
	print #f, "The integer square roots of powers of 7 from 7^23 up to 7^33 are:"
	decimal j,p
	for i=23 to 33 step 2 {
		p=1:for j=1 to i:p*=7@:next
		print #f, "IntSqrt(7^"+i+")="+comma$(IntSqrt(p))+" of 7^"+i+" ("+comma$(p)+")"
	}
	print #f
	
	
	function IntSqrt(x as double) {
		double q=1, z=x, t, r
		do q*=4 : until (q>x)
		while q>1
			q/=4:t=z-r-q:r/=2
			if t>-1 then z=t:r+= q
		end while
		=r
	}
	print #f, "Using Double Type"
	print #f, "The integer square roots of powers of 7 from 7^19 up to 7^35 are:"
	for i=19 to 35 step 2 {
		print #f, "IntSqrt(7^"+i+")="+comma$(IntSqrt(7^i))+" of 7^"+i+" ("+(7^i)+")"
	}
	print #f
	print #f, "Using BigInteger Type"
	
	function IntSqrt(x as BigInteger) {
		BigInteger q=1, z=x, t, r
		do q*=4 : until (q>x)
		while q>1
			q|div 4:t=z-r-q:r|div 2
			if t>-1 then z=t:r+= q
		end while
		=r
	}
	BigInteger Z=7
	z=modpow(7u, 19u, BigInteger("1"+String$("0", 100)))
	print #f, "The integer square roots of powers of 7 from 7^19 up to 7^35 are:"
	for i=19 to 73 step 2 {
		print #f, "IntSqrt(7^"+i+")="+comma$(IntSqrt(Z))+" of 7^"+i+" ("+comma$(Z)+")"
		Z*=7*7
	}
	print #f
		
}
open "" for output as #f  // f = -2 now, direct output to screen
integer_square_root
close #f
open "out.txt" for output as #f
	integer_square_root f
close #f
win "notepad", dir$+"out.txt"

Output:

The integer square root of integers from 0 to 65 are:

0 1 1 1 2 2 2 2 2 3 3 3 3 3 3 3 4 4 4 4 4 4 4 4 4 5 5 5 5 5 5 5 5 5 5 5 6 6 6 6 6 6 6 6 6 6 6 6 6 7 7 7 7 7 7 7 7 7 7 7 7 7 7 7 8 8

Using Long Long Type

The integer square roots of powers of 7 from 7^1 up to 7^21 are:

IntSqrt(7^1)=2 of 7^1 (7)

IntSqrt(7^3)=18 of 7^3 (343)

IntSqrt(7^5)=129 of 7^5 (16,807)

IntSqrt(7^7)=907 of 7^7 (823,543)

IntSqrt(7^9)=6,352 of 7^9 (40,353,607)

IntSqrt(7^11)=44,467 of 7^11 (1,977,326,743)

IntSqrt(7^13)=311,269 of 7^13 (96,889,010,407)

IntSqrt(7^15)=2,178,889 of 7^15 (4,747,561,509,943)

IntSqrt(7^17)=15,252,229 of 7^17 (232,630,513,987,207)

IntSqrt(7^19)=106,765,608 of 7^19 (11,398,895,185,373,143)

IntSqrt(7^21)=747,359,260 of 7^21 (558,545,864,083,284,007)

Using Decimal Type

The integer square roots of powers of 7 from 7^23 up to 7^33 are:

IntSqrt(7^23)=5,231,514,822 of 7^23 (27,368,747,340,080,916,343)

IntSqrt(7^25)=36,620,603,758 of 7^25 (1,341,068,619,663,964,900,807)

IntSqrt(7^27)=256,344,226,312 of 7^27 (65,712,362,363,534,280,139,543)

IntSqrt(7^29)=1,794,409,584,184 of 7^29 (3,219,905,755,813,179,726,837,607)

IntSqrt(7^31)=12,560,867,089,291 of 7^31 (157,775,382,034,845,806,615,042,743)

IntSqrt(7^33)=87,926,069,625,040 of 7^33 (7,730,993,719,707,444,524,137,094,407)

Using Double Type

The integer square roots of powers of 7 from 7^19 up to 7^35 are:

IntSqrt(7^19)=106,765,608 of 7^19 (1.13988951853731E+16)

IntSqrt(7^21)=747,359,260 of 7^21 (5.58545864083284E+17)

IntSqrt(7^23)=5,231,514,822 of 7^23 (2.73687473400809E+19)

IntSqrt(7^25)=36,620,603,758 of 7^25 (1.34106861966396E+21)

IntSqrt(7^27)=256,344,226,312 of 7^27 (6.57123623635343E+22)

IntSqrt(7^29)=1,794,409,584,184 of 7^29 (3.21990575581318E+24)

IntSqrt(7^31)=12,560,867,089,291 of 7^31 (1.57775382034846E+26)

IntSqrt(7^33)=87,926,069,625,040 of 7^33 (7.73099371970744E+27)

IntSqrt(7^35)=615,482,487,375,282 of 7^35 (3.78818692265665E+29)

Using BigInteger Type