Αναθεώρηση 22 (Έκδοση 8.9)

Ανέβηκε μια νέα αναθεώρηση με προχωρημένες λειτουργίες για το στοιχείο ελέγχου Λίστα (ListBox)

Το παράδειγμα έχει δυο λιστες (ListBox) το ένα δίπλα στο άλλο. Όταν μετακινούμε το ένα μετακινείται και το άλλο (ολισθαίνει δηλαδή πάνω και κάτω). Επιπλέον ο πίνακας στο δεύτερο είναι εξωτερικός. Εδώ η αλλαγή που έκανα είναι για να μπορεί να διορθώνεται ο εξωτερικός πίνακας, δηλαδή να του βάζουμε τιμές!
Το πρόγραμμα θα μπει στο τεύχος 34. Δεν έχει τελειώσει ακόμα το τεύχος αλλά σίγουρα θα γράφει πολλά πράγματα για το στοιχείο Λίστα!

Όρισε Φόρμα1 Φόρμα
Όρισε Λίστ1 Λίστα Φόρμα Φόρμα1
Όρισε Λίστ2 Λίστα Φόρμα Φόρμα1
Μέθοδος Λίστ1, "move", 2300,1000,2000,3000
Μέθοδος Λίστ2, "move", 4300,1000,4000,3000
Με Λίστ1, "ScrollTo" ως Ολισθ1, "ScrollFrom" ως Ολισθ1_τιμή, "DisplayLines", 5 ', "Transparent", Αληθές
Με Λίστ1, "listIndex2" ως Επιλ01, "listIndex" ως Επιλ1,"HideCaret", Αληθές ,  "ShowAlways", Αληθές
Με Λιστ2, "ScrollTo" ως Ολισθ2, "ScrollFrom" ως Ολισθ2_τιμή, "Edit",Αληθές,  "ShowAlways", Αληθές
Με Λίστ2, "listIndex2" ως Επιλ02, "listIndex" ως Επιλ2, "DisplayLines", 5
Με Λιστ1, "Title","Πεδία"
Με Λιστ2, "Title","Τιμές", "Center", Αληθές, "PanDouble", Αληθές
Με Λίστ1,"Text", {Όνομα
                                    Διεύθυνση1
                                    Διεύθυνση2
                                    Διεύθυνση3
                                    Πληροφορία1
                                    Πληροφορία2
                                    Πληροφορία3
                                    Πληροφορία4
                                    }
Πίνακας Βάση 0, α$(8)
α$(0)="Γιώργος"
Συνάρτηση Λιστ2.Listcount {
            Διάβασε Νέο &πόσα
            πόσα=8
}
Συνάρτηση Λιστ2.External {
      Διάβασε Νέο Που, &τι$
      τι$=α$(που)

}
Με Λίστ2, "External", Αληθές
Συνάρτηση Λιστ2.ValidList {
       Διάβασε Νέο &περιεχ$, &θεσηΧ, &στοιχειο
       Τύπωσε περιεχ$, θέσηΧ, στοιχείο : Ανανέωση
       α$(στοιχείο)=περιεχ$
}

Συνάρτηση Λιστ1.Color {
      Διάβασε Νέο &χρ
      Χρ=#FF3311
}
Συνάρτηση Λιστ2.Color {
      Διάβασε Νέο &χρ
      Χρ=#1133FF
}
Συνάρτηση Λιστ2.dblClick {
      Διαβασε που
      Τύπωσε "doule click", αριθμός, α$(που)
      Ανανέωση
}
Συνάρτηση Λιστ2.Click {
      Επιλ01=Επιλ2
      Επιλ2=Επιλ2
      Ολισθ1=Ολισθ2_τιμή
}
Συνάρτηση Λιστ1.Click {
      Επιλ02=Επιλ1
      Επιλ1=Επιλ1
      Ολισθ2=Ολισθ1_τιμή
}
Συνάρτηση Λιστ2.Scroll {
      Επιλ1=Επιλ2
      Ολισθ1=Ολισθ2_τιμή
}
Συνάρτηση Λιστ1.Scroll {
      Επιλ2=Επιλ1
      Ολισθ2=Ολισθ1_τιμή
}
Συνάρτηση Λιστ2.Move {
      Διάβασε Νέο πάνω1
      Επιλ01=Επιλ2
      Ολισθ1=πάνω1
}
Συνάρτηση Λιστ1.Move {
      Διάβασε Νέο πάνω1
      Επιλ02=Επιλ1
      Ολισθ2=πάνω1
}
Μέθοδος Φόρμα1, "Show", 1
Όρισε Φόρμα1 Τίποτα
Τύπωσε α$()